The SPARQL endpoint is hosted at http://rdf.neuinfo.org/sparql. It contains NIFSTD ontology data referenced as http://ontology.neuinfo.org as the default graph URI.  We also include RDF representations of certain NIF data sources, e.g., connectivity data.

We demonstrate a simple query that retrieves all the cerebellum GABA-ergic neurons.

prefix nifstd: <http://ontology.neuinfo.org>
prefix nm: <http://ontology.neuinfo.org/NIF/BiomaterialEntities/NIF-Molecule.owl#>
prefix be: <http://ontology.neuinfo.org/NIF/BiomaterialEntities/NIF-Neuron-BrainRegion-Bridge.owl#>
prefix nb: <http://ontology.neuinfo.org/NIF/BiomaterialEntities/NIF-Neuron-NT-Bridge.owl#>
prefix w3: <http://www.w3.org/2002/07/owl#>
prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix xsd: <http://www.w3.org/2001/XMLSchema#>

select ?e,?l 
where {
?e rdfs:label ?l .
?e rdfs:subClassOf ?hn .
?hn rdfs:label "Cerebellum neuron"^^xsd:string .
?e rdfs:subClassOf ?o .
?o w3:onProperty nb:has_neurotransmitter .
?o w3:someValuesFrom ?gaba .
?gaba rdfs:label "GABA"^^xsd:string
}

To execute the above query, place it in the dialog box "Query text" and press "Run Query". As mentioned before the "Default Graph URI" is http://ontology.neuinfo.org. By default the result is displayed in HTML table format as follows:

e

l

http://ontology.neuinfo.org/NIF/BiomaterialEntities/NIF-Cell.owl#sao471801888

Cerebellum Purkinje cell

http://ontology.neuinfo.org/NIF/BiomaterialEntities/NIF-Cell.owl#sao1415726815

Cerebellum Golgi Cell

http://ontology.neuinfo.org/NIF/BiomaterialEntities/NIF-Cell.owl#sao666951243 

Cerebellum basket cell

http://ontology.neuinfo.org/NIF/BiomaterialEntities/NIF-Cell.owl#nifext_130 

Cerebellum stellate cell

Here column "e" shows the NIFSTD name of the entity that match the query and column "l" holds their label. Its also possible to export the result in other formats such as CSV, JSON, NTriples, RDF/XML by choosing appropriate item from the "Display Result As" drop down menu.

Transitive query

We demonstrate a simple query that retrieves all neurons using Virtuoso's TRANSITIVE feature (a non-standard SPARQL extension).  It returns all descendants (via subClassOf) of sao1417703748.

prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix sao: <http://ontology.neuinfo.org/NIF/BiomaterialEntities/NIF-Cell.owl#>

SELECT ?y, ?yl
WHERE {
{{
  select *
  where
{
  ?y rdfs:subClassOf ?n
}
}
OPTION (TRANSITIVE, t_distinct, t_in(?n), t_out(?y) )
FILTER (?n = sao:sao1417703748) . ?y rdfs:label ?yl
}
}

To execute the above query, place it in the dialog box "Query text" and press "Run Query". As mentioned before the "Default Graph URI" is http://ontology.neuinfo.org.

We demonstrate a simple query that retrieves all brain regions using Virtuoso's TRANSITIVE feature (a non-standard SPARQL extension).  It returns all descendants (via subClassOf) of sao1417703748.

prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix br: <http://ontology.neuinfo.org/NIF/BiomaterialEntities/NIF-GrossAnatomy.owl#>

SELECT DISTINCT ?y, ?yl
WHERE {
{{
  select *
  where
{
  ?y rdfs:subClassOf ?n
}
}
OPTION (TRANSITIVE, t_distinct, t_in(?n), t_out(?y) )
FILTER (?n = br:birnlex_1167) . ?y rdfs:label ?yl
}
}

To execute the above query, place it in the dialog box "Query text" and press "Run Query". As mentioned before the "Default Graph URI" is http://ontology.neuinfo.org.

Connectivity query

PREFIX nif_cnxn: <http://connectivity.neuinfo.org#>

select DISTINCT $Globus_pallidus_strength $Globus_pallidus_receiving $Globus_pallidus_reference

{
$Globus_pallidus nif_cnxn:sending_structure  "Globus pallidus" .
$Globus_pallidus nif_cnxn:projection_strength $Globus_pallidus_strength .
$Globus_pallidus nif_cnxn:receiving_structure $Globus_pallidus_receiving .
$Globus_pallidus nif_cnxn:reference $Globus_pallidus_reference
}